addEventListener

handler 回调函数，如果指定了 eventType 则为一元函数，参数为匹配的事件。如果指定为按时间触发，则没有参数。

def actions1(stockVal){
    //将事件类型 stockVal 的属性写入一个共享表
    insert into objByName("sharedUSPrices") values([stockVal.price, stockVal.qty])
} 

handler 中可以动态添加新的监听器：

def actions1(stockVal){
    //将事件类型 stockVal 的属性写入一个共享表
    insert into objByName("sharedUSPrices") values([stockVal.price, stockVal.qty])
    //新增加一个事件侦听器
    addEventListener(handler=action2, eventType="Stock", condition=<self.prices > stockVal.price>)
}

自 3.00.4 版本起，handler 支持调用 monitor 类之外的函数。调用外部类的方法时，应使用 self（当前实例的引用）进行访问，例如：

class Logic{
    monitor::ANY 
    def Logic(monitor_){
        monitor = monitor_
    }
    def processTick(stockTickEvent) { 
        str = "StockTick event received" + 
                " name = " + stockTickEvent.name + 
                " Price = " + stockTickEvent.price.string()
        writeLog(str)
    }
    def testAddListener(){
        monitor.addEventListener(self.processTick, "StockTick", ,"all")
    }
}

name 字符串标量，可选参数，表示监听器的名称，用于唯一标识该监听器。默认值根据 condition 得出：

• 若指定 condition，则名称为其表达式的字符串形式；
• 若 condition 为空且指定了 eventType，则名称为 eventType；
• 若 condition 和 eventType 均未指定，则默认名称为 "timer"；
• 若生成的名称与现有监听器重名，将自动在名称后追加编号以确保唯一性。

class trades{
    trader :: STRING
    market :: STRING
    code :: STRING
    price :: DOUBLE
    qty :: INT
    eventTime :: TIMESTAMP
    def trades(t, m, c, p, q){
        trader = t
        market = m
        code = c
        price = p
        qty = q
        eventTime = now()
    }
}

class mainMonitor:CEPMonitor{
    tradesTable :: ANY
    isBusy :: BOOL
    def mainMonitor(){
        tradesTable = array(ANY, 0)
        isBusy = false
    }

    def updateTrades(event)

    def updateTrades2(event)

    def unOnload(){
        undef('traderDV', SHARED)
    }

    def onload(){
        addEventListener(updateTrades, `trades, , "all",,,,,"trades1")
        addEventListener(updateTrades2, `trades, , "all",,,,,"trades2")
        traderDV = streamTable(array(STRING, 0) as trader, array(STRING, 0) as market, array(SYMBOL, 0) as code, array(DOUBLE, 0) as price, array(INT, 0) as qty, array(INT, 0) as tradeCount, array(BOOL, 0) as busy, array(DATE, 0) as orderDate, array(TIMESTAMP, 0) as updateTime)
        share(traderDV, 'traderDV')
        createDataViewEngine('traderDV', objByName('traderDV'), `trader, `updateTime, true)
    }

    def updateTrades(event) {
        tradesTable.append!([event.trader, event.market, event.code, event.price, event.qty])
        getDataViewEngine('traderDV').append!(table(event.trader as trader, string() as market, string() as code, 0.0 as price, 0 as qty, 0 as tradeCount, false as busy, date(event.eventTime) as orderDate))
        updateDataViewItems('traderDV', event.trader, ['market', 'code', 'price', 'qty', 'tradeCount'], [event.market, event.code, event.price, event.qty, tradesTable.size()])
    }

    def updateTrades2(event) {
        tradesTable.append!([event.trader, event.market, event.code, event.price, event.qty])
        getDataViewEngine('traderDV').append!(table(event.trader as trader, string() as market, string() as code, 0.0 as price, 0 as qty, 0 as tradeCount, false as busy, date(event.eventTime) as orderDate))
        updateDataViewItems('traderDV', event.trader, ['market', 'code', 'price', 'qty', 'tradeCount'], [event.market, event.code, event.price, event.qty, tradesTable.size()])
    }
}

dummy = table(array(TIMESTAMP, 0) as eventTime, array(STRING, 0) as eventType, array(BLOB, 0) as blobs)
engineCep = createCEPEngine('cep1', <mainMonitor()>, dummy, [trades], 1, 'eventTime', 10000)
trade1 = trades('t1', 'sz', 's001', 11.0, 10)
go
appendEvent(engineCep, trade1)
// 查看 monitor
monitors = getCEPEngineMonitor('cep1',"cep1","mainMonitor")
// 查看 listener
listeners = monitors.getEventListener()
print(listeners)
// 终止 listener
listeners['trades1'].terminate()
print(listeners)

相关函数：getEventListener, terminate