北向资金加仓策略

策略通过 loadText 函数，将本地 CSV 文件中的基础行情与因子数据载入内存。数据表包含量价、涨跌停价，以及预先计算的三类选股因子：北向持股比例的 5 日增量、市盈率和净资产收益率。

读入宽表后，代码自动提取唯一的证券代码生成初始股票池，并基于该股票池在内存中构造了三张配套的辅助数据表以支持选股过滤逻辑：

1. 历史指数成分快照：将股票池内的代码与行情起始日期关联，生成统一的指数成分快照表。

2. ST 历史表：初始化包含证券代码、起止时间等标准字段的数据表，供状态过滤逻辑调用。

3. 上市时间信息表：为股票池中的所有股票统一配置基准上市日期（2010.01.01），以支持策略中关于上市满 90 天的条件筛选逻辑

data = loadText("/.../northboundNetBuyBarData.csv")
data.replaceColumn!("volume", long(data.volume))
//1. 股票池
stockPool = exec distinct symbol from data
// 2. 指数成分快照
n_ = size(stockPool)
snapDate_ = min(date(data.tradeTime))
tpIdxSnaps_ = table(take("000300.SH", n_) as index_code,
    take(snapDate_, n_) as snap_date,
    stockPool as con_code)

// 3. ST 历史：空表，表示没有 ST 股票
tpStHist_ = table(1:0, `code`start_date`period_end, [STRING, DATE, DATE])

// 4. 上市信息：所有股票上市日期统一设为 2010.01.01，确保上市满 90 天
tpListInfo_ = table(stockPool as code, take(2010.01.01, n_) as list_date)

在接入其他业务数据时，用户只需确保传入的数据表保留了相同的核心字段名称，无需修改前置的策略回调逻辑即可直接复用。准备就绪的全量数据将通过 Backtest::appendQuotationMsg 一次性推入引擎，并由 Backtest::appendEndMarker 标记行情回放结束。

策略中的 roundLot 和 normalizeSellQty 分别处理买入数量和卖出数量。普通股票以 100 股为单位；科创板、北交所、可转债和 ETF/LOF 保留相应的数量规则。

initialize 订阅预计算的 north_inc_5d 指标，并保存手续费、印花税、股票池和调仓状态。onBar 分两个阶段处理：先按上一个信号日锁定的目标数量执行调仓，再根据本交易日的因子生成下一次调仓计划。

调仓执行的关键逻辑如下：

if (context["pendingRebalance"] && curDate != context["rebalanceDate"]) {
    tgtQtys_ = context["pendingTargetQtys"]
    expectedCash_ = Backtest::getAvailableCash(context.engine)

    // 第一轮：卖出未入选股票或超配部分。
    for (istock in msg.keys()) {
        bar = msg[istock]
        posInfo = Backtest::getPosition(context.engine, istock)
        // 按 T+1 可卖数量限制卖出，并检查委托价是否位于涨跌停区间。
        ...
    }

    // 第二轮：按得分排名顺序买入新入选或仓位不足的股票。
    for (istock in context["selectedStocks"]) {
        if (!(istock in msg)) { continue }
        bar = msg[istock]
        if (!isOrderPriceValid(bar["open"], bar)) { continue }
        // 用预计剩余现金和引擎可用现金限制买入数量。
        ...
    }
    context["pendingRebalance"] = false
}

信号生成时，先根据历史成分股、ST 与上市日期筛选可交易池，提取通过硬门槛（如 north_inc_5d > 0）的三类有效因子，再进行横截面加权打分并计算目标股数：

// 横截面打分：北向增量(0.4)、PE低估值(0.3)、ROE高质量(0.3)，取得分最高的前10只
selectedStocks_ = []$STRING
if (size(symbols_) > 0) {
    factorT = table(symbols_ as symbol, northInc_ as north_inc, pe_ as pe, roe_ as roe)
    factorT = select symbol,
        (0.4 * (1.0 - rank(north_inc, false, percent=true))
            + 0.3 * (1.0 - rank(pe, true, percent=true))
            + 0.3 * (1.0 - rank(roe, false, percent=true))) as compositeScore
        from factorT
    scoreT = select symbol, compositeScore from factorT order by compositeScore desc, symbol asc limit 10
    selectedStocks_ = exec symbol from scoreT
}
context["selectedStocks"] = selectedStocks_

// 信号日收盘：按等权计算目标股数
if (size(selectedStocks_) > 0) {
    signalEquity_ = Backtest::getTotalPortfolios(context.engine).totalEquity.last()
    targetWeight = 1.0 / double(size(selectedStocks_))
    tgtQtys_ = dict(STRING, LONG)
    for (s_ in selectedStocks_) {
        tgtQtys_[s_] = roundLot(s_, signalEquity_ * targetWeight / (msg[s_]["close"] * (1 + context["commission"])))
    }
    context["pendingTargetQtys"] = tgtQtys_
    // ...
}

目标数量在信号日锁定，因此次日开盘跳空不会改变计划股数。实际成交仍会受可用现金、涨跌停、停牌、T+1 可卖数量和整手规则约束。若卖出委托未成交，计算买入可用资金时不计入对应的预计卖出收入。

回测参数与交易成本如下：

config = {
    startDate: 2024.01.01,
    endDate: 2024.12.31,
    strategyGroup: "stock",
    cash: 1000000.0,
    commission: 0.00015,
    tax: 0.0005,
    dataType: 4,
    outputOrderInfo: true,
    matchingMode: 2,
    orderBookMatchingRatio: 0.2,
    enableMinimumPerTransactionFee: false
}

初始资金为 1,000,000 元。手续费率为成交额的 0.015%，卖出印花税率为 0.05%。outputOrderInfo = true 会保留订单状态信息，因此 tradeDetails 可包含未成交或部分成交状态，不能将其行数直接等同于成交笔数。

回调函数注册到 callbacks 字典，然后创建回测引擎。运行前会尝试删除同名遗留引擎；结束后再次删除，避免会话内重复执行时发生名称冲突。

callbacks = dict(STRING, ANY)
callbacks["initialize"] = initialize
callbacks["onBar"] = onBar

engineName = "northboundAddPositionEngine"
try { Backtest::dropBacktestEngine(engineName) } catch(ex) { }
engine = Backtest::createBacktester(engineName, config, callbacks, false)

脚本按自然月循环准备行情和北向持股比例变化量，并把处理后的日线追加到引擎。示例版本从本地 CSV 文件加载数据；接入真实数据后，引擎输入流程保持不变：

Backtest::appendQuotationMsg(engine, data)
Backtest::appendEndMarker(engine);

末尾的 END 行用于通知引擎行情回放结束。它仅作为结束标记，不是可交易证券。

回测结束后读取收益汇总、订单明细、每日持仓和每日组合权益。示例脚本使用模拟日线构建 000300.SH 基准净值；接入真实数据时，应替换为沪深 300 指数的真实历史行情。

tradeDetails = Backtest::getTradeDetails(engine)
returnSummary = Backtest::getReturnSummary(engine)
dailyPosition = Backtest::getDailyPosition(engine)
totalPortfolios = Backtest::getDailyTotalPortfolios(engine)