启动脚本

下面代码中定义了一张内存表t，并分享为sharedT。在其他会话中可对表sharedT进行增加、更新、删除和查询记录。

t=table(1:0,`date`sym`val,[DATE,SYMBOL,INT])
share(t, `sharedT); 

流数据表的定义不可在DolphinDB中持久化保存，所以流数据表的初始化工作可在启动脚本中执行。下面代码加载并共享了流数据表st1：

login("admin","123456")
t1=streamTable(1:0,`date`sym`val,[DATE,SYMBOL,INT])
enableTableShareAndPersistence(table=t1,tableName=`st1,cacheSize=1000)

流数据表的订阅也可在启动脚本中完成。以下的代码中，订阅流数据表st1，并把订阅的数据保存到分布式数据表：

tb=loadTable("dfs://db1","tb")
subscribeTable(,"st1","subst",-1,append!{tb},true)

注意：在例子1，2的场景下，若在启动脚本中定义了共享内存表或者共享流数据表，且在启动脚本中调用了共享表变量，需要在 share 函数或者 enableTableShareAndPersistence 函数后增加 go 语句，否则解析会抛出异常。参考下例：

将流数据表的数据写入一个共享的键值表，在启动脚本中定义如下：

def saveT(tb,st){tb.append!(st)}

n=1000000
colNames = `time`sym`vwap
colTypes = [DATETIME,SYMBOL,DOUBLE]
share streamTable(n:0, colNames, colTypes) as test_stream
opt=keyedTable(`sym, n:0, colNames, colTypes)
share(opt, `optShared)
go
subscribeTable(tableName="test_stream", actionName="test1", offset=0, handler=saveT{optShared}, msgAsTable=true, batchSize=100000, throttle=60)

上例中，share(opt, `optShared) 语句执行时，动态注册了共享表对象optShared，而后续订阅的 handler=saveT 中调用了变量 optShared。若不增加 go 语句，系统解析时，由于无法识别动态注册的变量 optShared 会抛出异常。

为避免不加 go 语句导致的解析异常，也可以将上述 share 函数替换成 share 语句：

share opt as optShared

若定时作业 (scheduled job) 中使用了插件函数，必须在启动脚本中加载插件或者在配置项 preloadModules 配置插件，否则会因反序列化失败导致系统退出。 下列代码在定时作业中使用了ODBC插件：

use odbc
def jobDemo(){
	conn = odbc::connect("dsn=mysql_factorDBURL");
	//...
}
scheduleJob("job demo","example of init",jobDemo,15:48m, 2019.01.01, 2020.12.31, 'D')

若ODBC插件在系统启动时没有加载，读取定时作业时会无法识别函数 jobDemo，导致退出系统，输出下列日志：

<ERROR>:Failed to unmarshall the job [job demo]. Failed to deserialize assign statement. Invalid message format.

必须在启动脚本中加入下列代码以加载 ODBC 插件：

loadPlugin("plugins/odbc/odbc.cfg")

或者在配置项文件（单节点：dolphindb.cfg / 集群：cluster.cfg）中添加：

preloadModules=plugins::odbc