使用 DolphinDB 进行汽车用户驾驶习惯行为画像分析

用户的驾驶行为中的速度偏好可以通过多种数据指标来分析和表征。以下是几个主要的分析角度：

• 平均车速：通过车辆监控系统记录的平均车速数据，可以分析驾驶行程中低速、中速、高速的分布情况，进而得出此用户的速度偏好情况
• 加速踏板及制动踏板数据：加速踏板和制动踏板的使用频率和力度可以反映出驾驶的激烈程度。通过这些信号数据的平均值也可以量化驾驶员的速度偏好。

用户的驾驶风格反映了其在道路上的行为习惯和对安全性的关注程度。以下是几个关键的分析维度：

• 变道频率：通过车辆监控系统记录的变道次数和频率，可以分析驾驶员的变道习惯。激进驾驶者可能会频繁变换车道以寻求快速通行，而谨慎驾驶者则会尽量减少不必要的变道操作。
• 急加速和急刹车次数：频繁的急加速和急刹车通常反映出驾驶员的激进程度。这些数据可以通过监控加速踏板和制动踏板的使用情况来获取，从而量化驾驶风格的激进程度。
• 驾驶稳定性：驾驶稳定性可以通过车辆在行驶过程中的平稳性来衡量，例如持续速度的保持、转弯时的平稳操作等。平衡驾驶者通常会表现出相对稳定的驾驶行为，不会过于激进或过于保守。

驾驶熟练度反映了驾驶者对不同驾驶情境的熟悉程度和技能水平。以下是几个关键的分析维度：

• 驾驶经验：驾驶经验可以通过驾驶年限和驾驶里程来衡量。经验丰富的驾驶者通常能更好地应对复杂的驾驶情况和突发事件。
• 应对复杂路况的能力：分析驾驶者在面对交通拥堵、复杂路口和恶劣天气时的反应和应对能力。高熟练度的驾驶者可能会更快速、更准确地做出反应，保持驾驶的稳定性和安全性。

基于上述三个维度，我们模拟一个具有如下结构的车辆驾驶数据：

使用如下脚本模拟车辆的一段行程数据：

def simulateData(num,idNum,freq){
    setRandomSeed(10086)
    name = "user"+string(take(1..idNum,num))
    id = take(1..idNum,num)
    ts =stretch((now() + (1..int(num\idNum))*freq),num)
    totalMileage = rand(10000,idNum)
    t = table(name,id,ts)
    addColumn(t,[`totalMileage,`speed,`throttle,`brake,`lane],[DOUBLE,DOUBLE,DOUBLE,DOUBLE,INT])   
    for(i in 1..idNum){
        avg = rand(100,1)[0]
        std = rand(10,1)[0]
        speedTmp = randNormal(avg,std,int(num\idNum))
        totalMileageTmp = totalMileage[i-1]+cumsum(speedTmp/36000)
        avg = rand((avg-10)..(avg+10),1)[0]
        std = rand(10,1)[0]
        throttleTmp = randNormal(avg,std,int(num\idNum))
        avg = rand(100,1)[0]
        std = rand(10,1)[0]
        brakeTmp = randNormal(avg,std,int(num\idNum))
        laneTmp = stretch(rand(1..4,rand(1..(avg+1),1)[0]),int(num\idNum))
        update t set  speed = speedTmp where id = i
        update t set  throttle = throttleTmp where id = i
        update t set  brake = brakeTmp where id = i 
        update t set  lane = laneTmp where id = i 
        update t set  totalMileage = totalMileageTmp where id = i 
    }
    return t
}

//模拟数据总量
num = 1000000
//模拟车辆数
idNum = 100
//采集频率（ms)
freq = 100
t = simulateData(num,idNum,freq)

在速度偏好分析中，我们选定了车速、加速踏板及制动踏板数据三个角度来分析用户的速度偏好。根据我们模拟的数据，我们使用车速、油门位置和刹车位置数据作为这三个分析维度的表征。 利用车速的平均值表示驾驶过程中的速度，以及使用油门位置和刹车位置的平均值来分别表示驾驶过程中的加速和减速特征。在下文中，我们将速度偏好分为低速、中速、高速三类，以进行聚类分析。一般而言，速度平均值和油门位置平均值越高，则速度偏好越倾向于高速偏好。

数据预处理和特征提取部分，在 DolphinDB 使用一个 SQL 语句即可同时完成。

首先是对数据进行预处理，将异常数据进行规范化。在速度分析中，对速度、油门位置、刹车位置数据进行清洗，具体为将小于0的速度、油门位置、刹车位置数据赋值为0，大于100的油门位置、刹车位置数据赋值为100。在 DolphinDB 中使用 iif 函数即可实现简洁、高效的数据清洗。对清洗后数据按车辆维度进行聚合，即可获得速度平均值、油门平均值和刹车平均值等速度特征值。

为了消除不同特征间的量纲差异，我们可以直接调用 DolphinDB 的 zscore 函数对数据进行标准化处理：

speedFactor = select avg(iif(speed<0,0,speed)) as speed,
              avg(iif(throttle<0,0,iif(throttle>100,100,throttle))) as throttle,
              avg(iif(brake<0,0,iif(brake>100,100,brake))) as brake 
              from t group by id
              
update!(table = speedFactor,colNames = [`speed,`throttle,`brake],
newValues = <[zscore(speed),zscore(throttle),zscore(brake)]> )
speedFactor                     

获取特征值后，我们利用 DolphinDB 的 K-means 算法对用户进行分类，以确定他们的速度偏好。本文将用户的速度偏好分为三类：低速、中速和高速。通过调用 DolphinDB 的 kmeans 函数，即可以轻松完成模型的训练，还能利用该模型对新老用户的速度偏好进行分类预测。

model = kmeans(speedFactor[:,1:4],3,1000,,"k-means++")
speedFactor[`label] = model.kmeansPredict(speedFactor[:,1:4]) 
speedFactor

通过 K-means 算法对用户速度偏好进行聚类后，我们可以明显看出三类用户的分割界限清晰，分类效果较好。具体来看，低速偏好用户的车速、油门位置平均值较低，刹车位置的平均值较高，表明他们更倾向于保守和谨慎的驾驶风格；中速偏好用户的各项指标则处于中等水平，反映出他们在驾驶过程中较为平衡；而高速偏好用户的车速和油门位置的平均值较高，刹车位置平均值较低，显示出他们偏好快速行驶，驾驶风格更加激进。这些聚类结果为进一步分析用户行为、优化驾驶体验提供了重要依据。

分类效果图如下，采用 PCA 降维将特征维度降为二维，红点表示聚类中心，绿点表示高速偏好的用户，蓝点表示中速偏好用户，灰点表示低速偏好用户：

驾驶风格偏好将分为谨慎驾驶、平衡驾驶和激进驾驶三类，通过速度标准差，激进操作（包括急刹和急加速次数，变道次数）等数据进行反映。速度标准差越大，激进操作次数越多，表明该驾驶员更倾向于激进驾驶的风格。

第一步仍然是进行数据预处理和特征提取。首先，使用 iif 函数对数据进行预处理；接着，通过 deltas 函数计算油门和刹车位置的前后差值，并利用 iif 函数对这些差值进行分类，将大于20的差值归类为急刹车和急加速。同样地，通过 iif 函数统计车道前后变化情况，以确定变道次数。完成这些步骤后，按车辆维度聚合数据，提取出速度的标准差、急刹次数、急加速次数和变道次数等关键特征值。获取到特征值后，调用 zscore 函数对数据进行标准化处理：

styleFactor = select std(iif(speed<0,0,speed)) as speed,
sum(iif(deltas(iif(throttle<0,0,iif(throttle>100,100,throttle)))>20,1,0)) as throttleChangeCount,
sum(iif(deltas(iif(brake<0,0,iif(brake>100,100,brake)))>20,1,0)) as brakeChangeCount,
sum(iif(lane!=prev(lane),1,0)) as laneChangeCount 
from t group by id 

update!(table = styleFactor,
colNames = [`speed,`throttleChangeCount,`brakeChangeCount,`laneChangeCount],
newValues = <[zscore(speed),zscore(throttleChangeCount),zscore(brakeChangeCount),
	zscore(laneChangeCount)]>) 
styleFactor

调用Kmeans方法，对用户驾驶偏好进行建模，分为三类：

通过对驾驶风格偏好的聚类分析，我们将驾驶员分为三类：谨慎驾驶、平衡驾驶和激进驾驶。从聚类结果来看，这三类驾驶员的特征区分度明显。谨慎驾驶的驾驶员速度波动小，急刹车和急加速次数少，变道较谨慎，且占比相对较高，表明多数驾驶员倾向于稳健安全的驾驶风格。平衡驾驶的驾驶员表现出适度的速度变化，偶尔有急刹车和急加速操作，变道次数适中，通常在安全性和效率之间取得平衡。激进驾驶的驾驶员速度波动大，频繁急刹车、急加速和变道，占比较小但行车风格激进，可能在特定情况下追求操作的极限。

聚类效果图如下，采用 PCA 降维将特征维度降为二维，红点表示聚类中心，灰点表示激进风格的用户，绿点表示平衡风格的用户，蓝点表示谨慎风格的用户：

熟练度特征主要反应了驾驶人员的娴熟程度，在本节，采用驾驶总里程和行程中急刹的次数进行表征，其中急刹车次数反映了驾驶员的操作习惯和反应能力，用来表示用户面对复杂路况的能力。通过这两个指标驾驶人员分为新手、熟练和老手。

同理也是对数据进行特征提取，并进行模型训练。因为驾驶总里程是一个递增值，因此我们使用 last 函数取最后一个值作为特征值，急刹次数的特征提取同上节。特征提取后进行了归一化处理：

experienceFactor = select last(totalMileage) as totalMileage,
sum(iif(deltas(iif(brake<0,0,iif(brake>100,100,brake)))>20,1,0)) as brakeChangeCount
from t group by id
update!(table = experienceFactor,colNames = [`totalMileage,`brakeChangeCount],
newValues = <[zscore(totalMileage),zscore(brakeChangeCount)]>)
experienceFactor

训练模型，并预测得到分类结果：

model = kmeans(experienceFactor[:,1:3],3,1000,,"k-means++")
experienceFactor[`label] = model.kmeansPredict(experienceFactor[:,1:3]) 
experienceFactor

通过熟练度偏好的聚类分析，我们将驾驶人员分为新手、熟练驾驶员和老手三类。新手驾驶员的总里程较低，急刹车次数也较少，表现出较为谨慎但经验不足的驾驶特点；熟练驾驶员则在驾驶经验和操作能力上处于中等水平，总里程数较高，但急刹车次数也较高，驾驶行为相对激进但能够较好地应对日常驾驶情境；老手驾驶员总里程高，急刹车次数较少，展现出更成熟的驾驶技术和驾控自信。聚类结果清晰地反映了不同驾驶员在熟练度上的差异，有助于理解用户在驾驶过程中的经验层次。

具体聚类效果如下，指标本身是二维数据，不需要进行降维。红点表示各类别的聚类中心，蓝点表示老手，驾驶技术娴熟，灰点表示熟练加速员，绿点表示新手：