accumulate

accumulate(func, X, [init], [consistent=false])

或

func:A([init], X)（表示 consistent 为 false）

或

func:AC([init], X)（表示 consistent 为 true）

或

[func:AC([init], X )

或

[init] <operator>:AC X （表示 consistent 为 true）

func：函数。

• 当 func 是一元函数时，X 可以是非负整数、一元函数或空值。init 表示 func 的参数，必须指定。

• func 是二元函数时，X 是向量、矩阵或表。init 表示初始值。

• func 是三元函数时，X 必须是一个 Tuple，包含2个元素，分别表示 func 的后两个参数。

consistent：布尔值，默认 false，表示每次迭代输出的数据类型由实际计算结果决定。否则，每次迭代输出的数据类型将与第一次迭代输出值的数据类型保持一致。 注意，若迭代结果的数据形式不一致，只能指定 consistent = false，否则会报错。

其他相关的 cum 系列函数的参数说明和窗口计算规则请参考: 累计窗口系列（cum 系列）

• 当 func 是一元函数时，accumulate 先输出 init，再应用 func 在 init 上，然后迭代地应用 func 到前一个结果上，直至满足 X 指定地迭代条件后输出结果。

• X 为整数时，表示 func 进行迭代的次数，输出结果包含 X + 1 个元素。注意，X 为负数时，将按0处理。

• X 为一元函数时，表示终止条件，返回结果必须为一个布尔标量。若 X 应用在前一个结果上的返回值为 true，func 继续迭代；否则，func 停止迭代。

• X 没有设置或为 NULL，func 将进行迭代计算直至输出的结果与前一个结果相同时停止迭代。

• 当 func 是二元函数时，accumulate 先应用函数 / 运算符在 init 和 X[0] 上，再迭代地应用函数 / 运算符在前一个结果和当前元素上。当 init 缺失时，accumulate 返回值的第一个元素是 X[0]。accumulate 等同于下面伪代码的执行过程：

  result[0]=iif(init==NULL,X[0],<function>(init,X[0]));
  
  for(i:1~size(X)-1){
      result[i]=<function>(result[i-1], X[i]);
  }
  
  return result;

• 当 func 是三元函数时，其迭代规则等同于二元函数。

  2.00.13.5 之前版本，当 X 是非负整数、一元函数或空值时，若 func 是多元函数且仅有一个必填参数时，accumulate 将 func 视为多元函数。而在 2.00.13.5 及之后版本，accumulate 则将 func 视为一元函数。

  与 reduce 返回最后一个结果不同，accumulate 输出所有中间结果。

当func 是一元函数时：

通过以下方式定义一个一元函数：

def func1(x){
  if(x<5){
          return x*3
  }
  else{
          return x+3
  }
}

当 X 为整数时，输出结果长度为 X + 1：

accumulate(func1, 5, 1)

返回：[1,3,9,12,15,18]。

当 X 为一元函数 condition 时，第3次迭代时因 condition 返回 false，停止迭代并输出前 2 次的迭代结果。

def condition(x){
  return x<9
}
accumulate(func1, condition, 1)

返回：[1,3,9]。

当 X 为 NULL（或不指定）时，自定义函数 func2 作为迭代的函数。由于第 4 次迭代结果和第 3 次相同，停止迭代并输出前 3 次迭代结果。

def func2(x){
  if(x<5){
          return x*3
  }
  else{
          return 6
  }
}

accumulate(func2,NULL,1)

返回：[1,3,9,6]。

func 是二元函数时，在一个向量上执行 accumulate：

x = 1 2 3;
accumulate(add, 1 2 3);

返回：[1,3,6]。这样的运算等同于 [1, 1+2, 3+3]。

1 +:A x;

返回：[2,4,7]。这样的运算等同于 [1+1, 2+2, 4+3]。

accumulate(-, x, 2);

返回：[1,-1,-4]。这样的运算等同于 [2-1, 1-2, -1-3]。

accumulate(mul, x);

返回：[1,2,6]。这样的运算等同于 [1, 1*2, 2*3]。

通过以下方式计算累积因式分解：

def facts(a) {return 1*:A 1..a;};
facts 5;

返回：[1,2,6,24,120]

通过以下方式计算 log(1) 到 log(i) 之间的累加和。其中，第一行的结果用作第二行 accumulate 的第一个参数值：

def f1(a,b): a+log(b);
accumulate(f1, 1..5, 0);

返回：[0,0.693147,1.791759,3.178054,4.787492]。这等同于：0+log(1)=0, 0+log(2)=0.693147, 0.693147+log(3)=1.791759, ......

在下面这个例子中，由于忽略了初始条件，输入向量的第一个元素的数据类型决定了返回值的数据类型。

accumulate(f1, 1..5);

返回：[1,1.693147,2.791759,4.178053,5.787491]。

对一个矩阵执行 accumulate:

x=1..12$3:4;
x;

得到：

+ :A x;

得到：

func 是三元函数时：

def fun3(x,y,z){
  return x+y+z
}
accumulate(fun3,[[1,2,3],[10,10,10]],5)

返回：[16,28,41]。